Stronger_Cracker
- 25 Tem 2022
- 6,659 Mesaj
Aktiflik
Seviye
Deneyim
Herkese selamlar, bugün yeni bir seriye başlıyoruz Sıfırdan Zig Serisi #1: Zig Programlama Dili Nedir? Kurulum, İlk Program ve Temel Sözdizimi? elimden geldiğince anlatacağım. Eleştiriye her zaman açık biri olarak her insan gibi bende hata yapabilirim. Konu altından saygı çerçevesinde dile getirirseniz bilgi alış-verişi/beyin fırtınası yapabilirim. :͛)͛ Bu konuda Zig programlama dilinin ne olduğunu, hangi sorunları çözmeyi hedeflediğini, Linux, macOS ve Windows'ta kurulumunu, ilk programı, değişkenleri, veri tiplerini, kontrol yapılarını, dizileri, string'leri, fonksiyonları ve test yazmayı ele alacağız. Hem C, Go ya da Rust gibi dilleri bilenler hem de sistem programlamaya yeni başlayanlar için hazırlamaya çalıştım umarım beğenirsiniz.
Bu seri bir video eğitim serisi gibi ilerleyecek. Zig'i en temelinden alıp gerçek bir proje yazacak seviyeye kadar götüreceğiz. Seride adım adım şu başlıklara bakacağız:
+ Zig Programlama Dili Nedir? Kurulum, İlk Program ve Temel Sözdizimi (bu konu)
+ Struct, Enum, Union, Optional ve Hata Yönetimi
+ Pointer, Slice ve Bellek Yönetimi (Allocator, defer, errdefer)
+ Comptime ve Generic Programlama
+ Build Sistemi, Test ve Paket Yönetimi
+ std.Io ile Dosya, Ağ ve Eşzamanlılık, C ile Birlikte Çalışma ve Cross-Compile
Zig, Andrew Kelley tarafından geliştirilen, genel amaçlı, derlemeli ve statik tipli bir sistem programlama dilidir. Aynı zamanda bir araç zinciridir (toolchain): derleyici, build sistemi, test çalıştırıcısı, kod biçimlendirici ve C/C++ derleyici arayüzü tek bir programın içinde gelir. Dil, kar amacı gütmeyen Zig Software Foundation tarafından desteklenir ve MIT lisanslıdır.
Zig'in hedefi C'nin kullanıldığı alanlarda (işletim sistemleri, gömülü sistemler, oyun motorları, veritabanları, derleyiciler) daha güvenli, daha okunabilir ve daha az sürprizli bir alternatif sunmaktır. C ile aynı seviyede kontrol verir, ama C'nin tuzaklarının (önişlemci makroları, tanımsız davranışlar, gizli kurallar) çoğunu ortadan kaldırır.
+ Gizli bellek ayırma yok: Bellek ayıran her fonksiyon bir allocator parametresi alır. Standart kütüphane belleği sizin yerinize sessizce ayırmaz. Garbage collector yoktur.
+ Önişlemci ve makro yok: Kod üretme ve derleme zamanı hesaplama için ayrı bir dil yerine dilin kendisi kullanılır. Bu özelliğe comptime denir ve serinin dördüncü konusunda ele alınacak.
+ Hatalar değerdir: Hata fırlatma yoktur, hatalar fonksiyonun dönüş tipinin bir parçasıdır. Hatayı ele almazsanız derleyici sizi uyarır.
+ Açık ve tek yol: Bir işi yapmanın tek bir belirgin yolu olması hedeflenir. Dil küçüktür ve birkaç sayfalık belgeyle tamamen okunabilir.
+ C ile birlikte çalışma: Mevcut C kütüphaneleri Zig'den kullanılabilir. Zig derleyicisi aynı zamanda tam bir C derleyicisi olarak çalışır.
+ TigerBeetle: Finansal işlemler için tasarlanmış yüksek performanslı veritabanı Zig ile yazıldı.
+ Ghostty: Hızlı ve modern bir terminal emülatörü.
+ zig cc: Uber gibi şirketler Zig'in C/C++ derleyici arayüzünü cross-compile aracı olarak kullanıyor. Yani Zig dilini hiç yazmadan da Zig araç zincirinden faydalanabilirsiniz.
(İncelemeniz için kaynak: "Zig production users Bun TigerBeetle Ghostty" yazarsanız çıkar.)
İnternette bulduğunuz eski Zig örnekleri güncel sürümde derlenmeyebilir. Mesela Zig 0.16'da standart kütüphanedeki girdi/çıktı sistemi baştan tasarlandı (std.Io), eskiden yaygın kullanılan std.io.getStdOut() çağrısı artık yoktur ve main fonksiyonunun alabileceği parametreler değişti. std.ArrayList kullanımı da değişti. Bir kod derlenmiyorsa ilk bakılacak yer kodun hangi Zig sürümü için yazıldığıdır. (İncelemeniz için kaynak: "Zig 0.16.0 release notes std.Io" yazarsanız çıkar.)
Yeni bir sürüm çıktığında seriyi güncel tutmaya çalışacağım. Kurulu sürümü şu komutla öğrenebilirsiniz:
İndirme sayfasında her arşiv için bir SHA-256 değeri ve imza dosyası bulunur. İndirdiğiniz dosyanın değerini sayfadaki ile karşılaştırın:
Dağıtımların depolarındaki Zig sürümü resmi sürümün gerisinde kalabilir. Kurduktan sonra zig version çıktısına bakın. Birden fazla sürüm kullanmak istiyorsanız zigup ya da zvm gibi sürüm yöneticilerine bakabilirsiniz. Windows'ta arşivi elle de açabilirsiniz: zip dosyasını bir klasöre çıkarıp o klasörü sistem PATH değişkenine ekleyin.
+ VS Code: Marketten "Zig Language" eklentisini kurun, ZLS'i genelde eklenti kendisi indirip yönetir.
+ Neovim, Helix, Zed: ZLS'i LSP sunucusu olarak tanımlayarak kullanabilirsiniz.
+ Biçimlendirme: Zig'in kod biçimlendiricisi derleyicinin içindedir, ayrı bir araç kurmanız gerekmez. Zig topluluğunda herkes aynı biçimi kullanır.
+ zig run dosya.zig: Dosyayı derleyip hemen çalıştırır. Öğrenirken en çok kullanacağınız komut.
+ zig build-exe dosya.zig: Çalıştırılabilir dosya üretir.
+ zig test dosya.zig: Dosyadaki test bloklarını çalıştırır.
+ zig fmt: Kodu biçimlendirir.
+ zig init: Boş bir klasörde build.zig, build.zig.zon ve kaynak klasörünü içeren örnek proje iskeleti oluşturur.
+ zig build: build.zig dosyasına göre projeyi derler. zig build run ile derleyip çalıştırır. Serinin beşinci konusunda detaylı anlatılacak.
+ zig cc / zig c++: Zig'i C ve C++ derleyicisi olarak kullanır.
+ zig env, zig targets: Ortam bilgisini ve derleme yapılabilecek hedef platformları gösterir.
Bu kodu satır satır inceleyelim:
+ const std = @import("std"); Standart kütüphaneyi içe aktarır. @ ile başlayan fonksiyonlar derleyiciye ait yerleşik (builtin) fonksiyonlardır. Bir dosya Zig'de bir struct gibi davrandığı için @import bir değer döndürür ve const'a atanır.
+ pub fn main(...) !void: Programın giriş noktasıdır. pub fonksiyonun dışarıya açık olduğunu gösterir. Dönüş tipindeki ! işareti bu fonksiyonun hata döndürebileceğini söyler, void ise başarılı olduğunda değer döndürmediğini. Hata yönetimi ikinci konuda detaylı anlatılacak.
+ init: std.process.Init: Zig 0.16 ile gelen "juicy main" özelliğidir. Program başlarken size hazır bir I/O nesnesi (init.io), genel amaçlı bir allocator (init.gpa), bir arena allocator (init.arena) ve komut satırı argümanlarını verir. Girdi/çıktı işlemleri artık bu nesne üzerinden yapılır, gizli global durum yoktur. Zig'in "gizli bir şey yok" felsefesinin bir sonucudur.
+ try: Yazma işlemi hata verebilir. try hata olursa fonksiyonu o hatayla sonlandırır, olmazsa devam eder.
Burada .{ ... } sözdizimi bir argüman listesidir (anonim struct). İlk parametre biçim metni, ikinci parametre bu metindeki {} yerlerine konacak değerlerin listesidir. Değer yoksa boş bırakılır: .{}
(İncelemeniz için kaynak: "Zig 0.16 std.Io File Writer stdout buffered" yazarsanız çıkar.)
+ pub fn main() !void: Hata döndürebilir. Hata dönerse program hata adını ve çağrı izini (stack trace) yazıp hata koduyla çıkar.
+ pub fn main(init: std.process.Init) !void: I/O, allocator, argümanlar ve ortam değişkenlerini hazır alır. Gerçek programlarda tercih edilen biçim.
zig run komutunda -- işaretinden sonrası programa gönderilen argümanlardır. (İncelemeniz için kaynak: "Zig 0.16 Juicy Main init.minimal.args" yazarsanız çıkar.)
Zig'de blok yorum (/* ... */) yoktur, yalnızca satır yorumları vardır. Bu, kodun parçalarını yanlışlıkla yorumlamayı ve araçların kodu ayrıştırmasını kolaylaştırır.
Zig'in değişkenlerle ilgili katı kuralları vardır:
+ Kullanılmayan değişken hatadır. Uyarı değil, derleme hatasıdır. Bilerek kullanmıyorsanız _ = degisken; yazarak derleyiciye bunu belirtirsiniz. Fonksiyon parametreleri için de geçerlidir.
+ Hiç değiştirilmeyen var hatadır. Bir var tanımlayıp hiç değiştirmezseniz derleyici const kullanmanızı ister.
+ Gölgeleme (shadowing) yasaktır. Üst kapsamdaki aynı isimle yeni bir değişken tanımlayamazsınız. Bu, hatalara yol açan sessiz ad çakışmalarını önler.
+ Başlatılmamış değişken yoktur. Değer atamadan değişken tanımlayamazsınız. Gerçekten sonra atamak istiyorsanız undefined kullanırsınız, bunu okumadan önce mutlaka değer atamalısınız.
+ Fonksiyonlar: camelCase (mesela harfNotu). Tip döndüren fonksiyonlar PascalCase olur.
+ Tipler (struct, enum): PascalCase (mesela OgrenciKaydi)
+ İşaretsiz tam sayılar: u8, u16, u32, u64, u128.
+ Herhangi genişlikte tam sayı: u3, i7, u24 gibi. Zig'e özgü bir özelliktir, bit alanları ve protokoller için kullanışlıdır.
+ usize ve isize: Platformun işaretçi genişliğinde tam sayı (64 bit sistemde 64 bit). Dizi uzunluğu ve indisleri usize tipindedir.
+ Ondalıklı sayılar: f16, f32, f64, f80, f128.
+ bool: true ya da false. Tam sayı olarak kullanılamaz.
+ void: Değer yok. Bellekte yer kaplamaz.
+ comptime_int, comptime_float: Derleme zamanında sınırsız hassasiyetle çalışan sayı tipleri. 5 gibi bir sayı literali önce bu tiptedir, sonra gereken tipe dönüşür.
+ type: Tipin kendisi bir değerdir. Comptime konusunda detaylı anlatılacak.
+ {s}: String ([]const u8).
+ {c}: Tek bir ASCII karakter.
+ {x}, {b}, {o}: Onaltılık, ikili ve sekizlik.
+ {e}: Bilimsel gösterim.
+ {any}: Herhangi bir tipi yazdırır. Dizileri ve struct'ları görmek için kullanışlıdır.
+ {d:.2}, {d:>6}: Virgülden sonra 2 basamak ve 6 karakter genişlikte sağa yaslı.
+ {{ ve }}: Süslü parantezin kendisini yazdırmak için çift yazılır.
+ @as(T, değer): Güvenli, açık tip belirleme.
+ @intCast(x): Tam sayıyı başka bir tam sayı tipine çevirir. Değer sığmazsa Debug ve ReleaseSafe modlarında program çöker (panic). Hedef tip, atamanın solundaki tipten alınır.
+ @truncate(x): Fazla bitleri keserek küçültür, çökmez.
+ @floatFromInt(x), @intFromFloat(x): Tam sayı ile ondalıklı arasında dönüşüm. Ondalıklıdan tam sayıya çevirirken küsurat atılır.
Tam sayı ile ondalıklıyı doğrudan toplayamazsınız, önce birini dönüştürmeniz gerekir. Bu sıkıcı görünebilir ama bilgi kaybına yol açan sessiz dönüşümleri tamamen ortadan kaldırır.
+ Karşılaştırma: ==, !=, <, >, <=, >=
+ Mantıksal: and, or, ! (&& ve || yoktur, kelimelerle yazılır)
+ Bit işlemleri: &, |, ^, ~, <<, >>
+ Atama: =, +=, -=, *=, /= vb. (++ ve -- yoktur, i += 1 yazılır)
İşaretli tam sayılarda / ve % operatörleri doğrudan kullanılamaz. Negatif sayıda sonuç belirsiz olabileceği için @divTrunc, @divFloor, @mod ya da @rem gibi hangi davranışı istediğinizi belirten fonksiyonlar kullanılır.
+ +%, -%, *%: Sarmal (wrapping) aritmetik, taşınca başa döner.
+ +|, -|, *|: Doygun (saturating) aritmetik, tipin sınırında kalır.
+ @addWithOverflow, @subWithOverflow, @mulWithOverflow: Sonucu ve taşma bayrağını birlikte döndürür.
+ std.math.add, sub, mul: Taşarsa error.Overflow hatası döndürür.
Burada a sabit ve değeri derleme zamanında bilindiği için düz a + 10 yazsaydınız taşma derleme hatası olurdu. Değer çalışma zamanında gelseydi program çökerdi. Derleme modları bölümünde ReleaseFast'te bu kontrollerin kapandığını göreceğiz.
Bu seri bir video eğitim serisi gibi ilerleyecek. Zig'i en temelinden alıp gerçek bir proje yazacak seviyeye kadar götüreceğiz. Seride adım adım şu başlıklara bakacağız:
+ Zig Programlama Dili Nedir? Kurulum, İlk Program ve Temel Sözdizimi (bu konu)
+ Struct, Enum, Union, Optional ve Hata Yönetimi
+ Pointer, Slice ve Bellek Yönetimi (Allocator, defer, errdefer)
+ Comptime ve Generic Programlama
+ Build Sistemi, Test ve Paket Yönetimi
+ std.Io ile Dosya, Ağ ve Eşzamanlılık, C ile Birlikte Çalışma ve Cross-Compile
Zig Programlama Dili Nedir?
Zig, Andrew Kelley tarafından geliştirilen, genel amaçlı, derlemeli ve statik tipli bir sistem programlama dilidir. Aynı zamanda bir araç zinciridir (toolchain): derleyici, build sistemi, test çalıştırıcısı, kod biçimlendirici ve C/C++ derleyici arayüzü tek bir programın içinde gelir. Dil, kar amacı gütmeyen Zig Software Foundation tarafından desteklenir ve MIT lisanslıdır.
Zig'in hedefi C'nin kullanıldığı alanlarda (işletim sistemleri, gömülü sistemler, oyun motorları, veritabanları, derleyiciler) daha güvenli, daha okunabilir ve daha az sürprizli bir alternatif sunmaktır. C ile aynı seviyede kontrol verir, ama C'nin tuzaklarının (önişlemci makroları, tanımsız davranışlar, gizli kurallar) çoğunu ortadan kaldırır.
Zig'in Temel Felsefesi?
+ Gizli kontrol akışı yok: Kodu okurken hiçbir satırın arka planda başka bir fonksiyonu çağırmadığını bilirsiniz. Operatör aşırı yükleme (operator overloading) ve exception yoktur. Bir fonksiyon çağrısı görmüyorsanız çağrı yoktur.+ Gizli bellek ayırma yok: Bellek ayıran her fonksiyon bir allocator parametresi alır. Standart kütüphane belleği sizin yerinize sessizce ayırmaz. Garbage collector yoktur.
+ Önişlemci ve makro yok: Kod üretme ve derleme zamanı hesaplama için ayrı bir dil yerine dilin kendisi kullanılır. Bu özelliğe comptime denir ve serinin dördüncü konusunda ele alınacak.
+ Hatalar değerdir: Hata fırlatma yoktur, hatalar fonksiyonun dönüş tipinin bir parçasıdır. Hatayı ele almazsanız derleyici sizi uyarır.
+ Açık ve tek yol: Bir işi yapmanın tek bir belirgin yolu olması hedeflenir. Dil küçüktür ve birkaç sayfalık belgeyle tamamen okunabilir.
+ C ile birlikte çalışma: Mevcut C kütüphaneleri Zig'den kullanılabilir. Zig derleyicisi aynı zamanda tam bir C derleyicisi olarak çalışır.
Zig Kimler Tarafından Kullanılıyor?
+ Bun: Hızıyla bilinen JavaScript çalışma ortamı Zig ile yazıldı.+ TigerBeetle: Finansal işlemler için tasarlanmış yüksek performanslı veritabanı Zig ile yazıldı.
+ Ghostty: Hızlı ve modern bir terminal emülatörü.
+ zig cc: Uber gibi şirketler Zig'in C/C++ derleyici arayüzünü cross-compile aracı olarak kullanıyor. Yani Zig dilini hiç yazmadan da Zig araç zincirinden faydalanabilirsiniz.
(İncelemeniz için kaynak: "Zig production users Bun TigerBeetle Ghostty" yazarsanız çıkar.)
Zig, C, Rust ve Go Arasındaki Farklar?
Zig ve C
Zig, C'nin yerine geçmeyi hedefler. Başlık dosyası (header) ve önişlemci yoktur, build sistemi dilin içindedir, çalışma zamanı kontrolleri (taşma, dizi sınırı, null) Debug ve ReleaseSafe modlarında varsayılan olarak açıktır. Mevcut C kodunu doğrudan kullanabilirsiniz.Zig ve Rust
Rust bellek güvenliğini derleme zamanında ownership ve borrow checker ile sağlar. Zig'de böyle bir sistem yoktur, bellek yönetimi geliştiricinin sorumluluğundadır ama allocator'lar, defer ve çalışma zamanı kontrolleri hata yapmayı zorlaştırır. Zig dili Rust'a göre çok daha küçüktür ve öğrenme eğrisi daha düşüktür. Ama Rust'ın derleme zamanı garantilerini sunmaz.Zig ve Go
Go garbage collector kullanır ve goroutine ile eşzamanlılığı dilin içine gömer. Zig'de garbage collector yoktur, bellek açıkça yönetilir ve çalışma zamanı minimaldir. Go ile karşılaştırıldığında Zig daha düşük seviyelidir, gömülü sistemler ve çekirdek geliştirme gibi alanlarda kullanılabilir. Go serisini daha önce okuyanlar için fark, Zig'de "her şeyi görmek" ve "her şeyi kontrol etmek" anlayışıdır.Sürüm Uyarısı: Zig 1.0 Öncesi Bir Dildir?
Zig henüz 1.0 sürümüne ulaşmadı. 1.0 öncesi sürümlerde dil ve standart kütüphane sürümler arasında kırıcı değişiklikler alabiliyor. Konu hazırlanırken güncel kararlı sürüm 0.17.0 idi, serideki tüm kodlar bu sürüme göre yazıldı.İnternette bulduğunuz eski Zig örnekleri güncel sürümde derlenmeyebilir. Mesela Zig 0.16'da standart kütüphanedeki girdi/çıktı sistemi baştan tasarlandı (std.Io), eskiden yaygın kullanılan std.io.getStdOut() çağrısı artık yoktur ve main fonksiyonunun alabileceği parametreler değişti. std.ArrayList kullanımı da değişti. Bir kod derlenmiyorsa ilk bakılacak yer kodun hangi Zig sürümü için yazıldığıdır. (İncelemeniz için kaynak: "Zig 0.16.0 release notes std.Io" yazarsanız çıkar.)
Yeni bir sürüm çıktığında seriyi güncel tutmaya çalışacağım. Kurulu sürümü şu komutla öğrenebilirsiniz:
Kod:
zig version
Zig Nasıl Kurulur?
Zig tek bir arşiv olarak dağıtılır. Kurulum sihirbazı yoktur, arşivi açıp klasörü PATH'e eklemeniz yeterlidir. Resmi adres ziglang.org/download sayfasıdır, sürüm numarası değiştikçe aşağıdaki adreslerdeki sürüm kısmını güncelleyin.Linux
Kod:
𖣘 Arşivi indir (mimarinize uygun olanı seçin, mesela x86_64)
wget https://ziglang.org/download/0.17.0/zig-x86_64-linux-0.17.0.tar.xz
𖣘 Arşivi aç ve /opt altına taşı
tar -xf zig-x86_64-linux-0.17.0.tar.xz
sudo mv zig-x86_64-linux-0.17.0 /opt/zig
𖣘 PATH'e ekle
echo 'export PATH="/opt/zig:$PATH"' >> ~/.bashrc
source ~/.bashrc
𖣘 Kontrol
zig version
İndirme sayfasında her arşiv için bir SHA-256 değeri ve imza dosyası bulunur. İndirdiğiniz dosyanın değerini sayfadaki ile karşılaştırın:
Kod:
sha256sum zig-x86_64-linux-0.17.0.tar.xz
Paket Yöneticileriyle
Kod:
𖣘 macOS (Homebrew)
brew install zig
𖣘 Windows (winget ya da Scoop)
winget install zig.zig
scoop install zig
𖣘 Arch Linux
sudo pacman -S zig
𖣘 Snap
sudo snap install zig --classic --beta
Dağıtımların depolarındaki Zig sürümü resmi sürümün gerisinde kalabilir. Kurduktan sonra zig version çıktısına bakın. Birden fazla sürüm kullanmak istiyorsanız zigup ya da zvm gibi sürüm yöneticilerine bakabilirsiniz. Windows'ta arşivi elle de açabilirsiniz: zip dosyasını bir klasöre çıkarıp o klasörü sistem PATH değişkenine ekleyin.
Kurulum Olmadan Denemek
Bir şey kurmadan denemek isterseniz Compiler Explorer (godbolt.org) üzerinde Zig derleyicisini seçip kod yazabilirsiniz. Üretilen assembly çıktısını görmek için de iyidir. (İncelemeniz için kaynak: "Compiler Explorer Zig" yazarsanız çıkar.)Editör Kurulumu ve ZLS?
+ ZLS (Zig Language Server): Kod tamamlama, tanıma git, hata gösterimi ve yeniden adlandırma sağlar. ZLS sürümü kullandığınız Zig sürümüyle uyumlu olmalıdır. Uyumsuz sürüm yanlış hata göstergeleri üretir.+ VS Code: Marketten "Zig Language" eklentisini kurun, ZLS'i genelde eklenti kendisi indirip yönetir.
+ Neovim, Helix, Zed: ZLS'i LSP sunucusu olarak tanımlayarak kullanabilirsiniz.
+ Biçimlendirme: Zig'in kod biçimlendiricisi derleyicinin içindedir, ayrı bir araç kurmanız gerekmez. Zig topluluğunda herkes aynı biçimi kullanır.
Kod:
𖣘 Tek bir dosyayı ya da tüm klasörü biçimlendir
zig fmt merhaba.zig
zig fmt .
Temel Zig Komutları?
+ zig run dosya.zig: Dosyayı derleyip hemen çalıştırır. Öğrenirken en çok kullanacağınız komut.
+ zig build-exe dosya.zig: Çalıştırılabilir dosya üretir.
+ zig test dosya.zig: Dosyadaki test bloklarını çalıştırır.
+ zig fmt: Kodu biçimlendirir.
+ zig init: Boş bir klasörde build.zig, build.zig.zon ve kaynak klasörünü içeren örnek proje iskeleti oluşturur.
+ zig build: build.zig dosyasına göre projeyi derler. zig build run ile derleyip çalıştırır. Serinin beşinci konusunda detaylı anlatılacak.
+ zig cc / zig c++: Zig'i C ve C++ derleyicisi olarak kullanır.
+ zig env, zig targets: Ortam bilgisini ve derleme yapılabilecek hedef platformları gösterir.
İlk Program: Merhaba Zig?
merhaba.zig adında bir dosya oluşturup aşağıdaki kodu yazın:
Kod:
const std = @import("std");
const Io = std.Io;
pub fn main(init: std.process.Init) !void {
try Io.File.stdout().writeStreamingAll(init.io, "Merhaba, Zig!\n");
}
Kod:
zig run merhaba.zig
𖣘 Çıktı: Merhaba, Zig!
Bu kodu satır satır inceleyelim:
+ const std = @import("std"); Standart kütüphaneyi içe aktarır. @ ile başlayan fonksiyonlar derleyiciye ait yerleşik (builtin) fonksiyonlardır. Bir dosya Zig'de bir struct gibi davrandığı için @import bir değer döndürür ve const'a atanır.
+ pub fn main(...) !void: Programın giriş noktasıdır. pub fonksiyonun dışarıya açık olduğunu gösterir. Dönüş tipindeki ! işareti bu fonksiyonun hata döndürebileceğini söyler, void ise başarılı olduğunda değer döndürmediğini. Hata yönetimi ikinci konuda detaylı anlatılacak.
+ init: std.process.Init: Zig 0.16 ile gelen "juicy main" özelliğidir. Program başlarken size hazır bir I/O nesnesi (init.io), genel amaçlı bir allocator (init.gpa), bir arena allocator (init.arena) ve komut satırı argümanlarını verir. Girdi/çıktı işlemleri artık bu nesne üzerinden yapılır, gizli global durum yoktur. Zig'in "gizli bir şey yok" felsefesinin bir sonucudur.
+ try: Yazma işlemi hata verebilir. try hata olursa fonksiyonu o hatayla sonlandırır, olmazsa devam eder.
std.debug.print ile Hızlı Çıktı
Öğrenirken ve hata ayıklarken en pratik yol std.debug.print kullanmaktır. Bu fonksiyon hata vermez ve Init gerektirmez, bu yüzden main fonksiyonu basit kalır. Ama çıktıyı stdout'a değil stderr'e yazar, yani çıktıyı > ile bir dosyaya yönlendirirseniz içine yazılmaz. Gerçek programların çıktısı için yukarıdaki stdout yöntemini kullanın. Bu serideki örneklerin çoğunda std.debug.print kullanacağım.
Kod:
const std = @import("std");
pub fn main() void {
std.debug.print("Merhaba, {s}!\n", .{"Zig"});
}
Burada .{ ... } sözdizimi bir argüman listesidir (anonim struct). İlk parametre biçim metni, ikinci parametre bu metindeki {} yerlerine konacak değerlerin listesidir. Değer yoksa boş bırakılır: .{}
Tamponlu Çıktı (Buffered Writer)
Çok sayıda satır yazan programlarda her yazmada işletim sistemine gitmek yavaştır. Bunun için bir tampon (buffer) verip writer oluşturulur. Tampon dolunca ya da flush çağrılınca yazılır. flush'ı unutursanız son çıktılar görünmeyebilir:
Kod:
const std = @import("std");
pub fn main(init: std.process.Init) !void {
const stdout = std.Io.File.stdout();
var buffer: [256]u8 = undefined;
var writer = stdout.writer(init.io, &buffer);
try writer.interface.print("Dil: {s}, sürüm: {d}\n", .{ "Zig", 17 });
try writer.interface.flush();
}
(İncelemeniz için kaynak: "Zig 0.16 std.Io File Writer stdout buffered" yazarsanız çıkar.)
main Fonksiyonunun Biçimleri
+ pub fn main() void: En basit biçim. Hata döndüremez, Init almaz.+ pub fn main() !void: Hata döndürebilir. Hata dönerse program hata adını ve çağrı izini (stack trace) yazıp hata koduyla çıkar.
+ pub fn main(init: std.process.Init) !void: I/O, allocator, argümanlar ve ortam değişkenlerini hazır alır. Gerçek programlarda tercih edilen biçim.
Komut Satırı Argümanları
Kod:
const std = @import("std");
pub fn main(init: std.process.Init) !void {
const args = try init.minimal.args.toSlice(init.arena.allocator());
for (args, 0..) |arg, i| {
std.debug.print("arg[{d}] = {s}\n", .{ i, arg });
}
}
Kod:
zig run argumanlar.zig -- elma armut
𖣘 Çıktı:
𖣘 arg[0] = ...(program yolu)
𖣘 arg[1] = elma
𖣘 arg[2] = armut
zig run komutunda -- işaretinden sonrası programa gönderilen argümanlardır. (İncelemeniz için kaynak: "Zig 0.16 Juicy Main init.minimal.args" yazarsanız çıkar.)
Yorum Satırları?
Kod:
// Bu bir yorum satırıdır
const x = 5; // satır sonuna da yazılabilir
/// Bu bir belge yorumudur (doc comment), altındaki tanımı açıklar
fn selamla() void {}
//! Bu bir modül belge yorumudur, dosyanın en üstüne yazılır
Zig'de blok yorum (/* ... */) yoktur, yalnızca satır yorumları vardır. Bu, kodun parçalarını yanlışlıkla yorumlamayı ve araçların kodu ayrıştırmasını kolaylaştırır.
Değişkenler?
Zig'de iki tür değişken tanımı vardır: değiştirilemeyen const ve değiştirilebilen var. Varsayılan tercih her zaman const olmalıdır.
Kod:
const std = @import("std");
pub fn main() void {
const dil = "Zig"; // değiştirilemez, tipi derleyici bulur
var surum: u32 = 17; // değiştirilebilir, tip açık yazıldı
const pi: f64 = 3.14159;
var sayac = @as(u8, 0); // başlangıç değeriyle tip belirleme
surum += 1;
sayac += 5;
std.debug.print("{s} {d} {d:.2} {d}\n", .{ dil, surum, pi, sayac });
// Çıktı: Zig 18 3.14 5
}
Zig'in değişkenlerle ilgili katı kuralları vardır:
+ Kullanılmayan değişken hatadır. Uyarı değil, derleme hatasıdır. Bilerek kullanmıyorsanız _ = degisken; yazarak derleyiciye bunu belirtirsiniz. Fonksiyon parametreleri için de geçerlidir.
+ Hiç değiştirilmeyen var hatadır. Bir var tanımlayıp hiç değiştirmezseniz derleyici const kullanmanızı ister.
+ Gölgeleme (shadowing) yasaktır. Üst kapsamdaki aynı isimle yeni bir değişken tanımlayamazsınız. Bu, hatalara yol açan sessiz ad çakışmalarını önler.
+ Başlatılmamış değişken yoktur. Değer atamadan değişken tanımlayamazsınız. Gerçekten sonra atamak istiyorsanız undefined kullanırsınız, bunu okumadan önce mutlaka değer atamalısınız.
Kod:
pub fn main() void {
const kullanilmayan = 10;
_ = kullanilmayan; // derleyiciyi susturur
var toplam: i32 = undefined; // henüz değer yok, okumadan önce atayın
toplam = 0;
_ = toplam;
}
İsimlendirme Kuralları
+ Değişkenler ve sabitler: snake_case (mesela not_ortalamasi)+ Fonksiyonlar: camelCase (mesela harfNotu). Tip döndüren fonksiyonlar PascalCase olur.
+ Tipler (struct, enum): PascalCase (mesela OgrenciKaydi)
Veri Tipleri?
+ İşaretli tam sayılar: i8, i16, i32, i64, i128. Sayı bit sayısını gösterir.+ İşaretsiz tam sayılar: u8, u16, u32, u64, u128.
+ Herhangi genişlikte tam sayı: u3, i7, u24 gibi. Zig'e özgü bir özelliktir, bit alanları ve protokoller için kullanışlıdır.
+ usize ve isize: Platformun işaretçi genişliğinde tam sayı (64 bit sistemde 64 bit). Dizi uzunluğu ve indisleri usize tipindedir.
+ Ondalıklı sayılar: f16, f32, f64, f80, f128.
+ bool: true ya da false. Tam sayı olarak kullanılamaz.
+ void: Değer yok. Bellekte yer kaplamaz.
+ comptime_int, comptime_float: Derleme zamanında sınırsız hassasiyetle çalışan sayı tipleri. 5 gibi bir sayı literali önce bu tiptedir, sonra gereken tipe dönüşür.
+ type: Tipin kendisi bir değerdir. Comptime konusunda detaylı anlatılacak.
Kod:
const std = @import("std");
pub fn main() void {
const a: i8 = -128;
const b: u8 = 255;
const c: i64 = 9_000_000_000; // _ ile okunabilirlik
const d: u3 = 7; // 3 bitlik işaretsiz tam sayı (0-7)
const e: usize = 100;
const f: f32 = 1.5;
const g: f64 = 2.5e3;
const h: bool = true;
const harf: u8 = 'Z'; // karakter, aslında bir bayt değeridir
std.debug.print("{d} {d} {d} {d} {d}\n", .{ a, b, c, d, e });
// Çıktı: -128 255 9000000000 7 100
std.debug.print("{d} {d} {} {c}\n", .{ f, g, h, harf });
// Çıktı: 1.5 2500 true Z
std.debug.print("i32: {d} bayt, u64: {d} bayt\n", .{ @sizeOf(i32), @sizeOf(u64) });
// Çıktı: i32: 4 bayt, u64: 8 bayt
std.debug.print("u8 aralığı: {d} - {d}\n", .{ std.math.minInt(u8), std.math.maxInt(u8) });
// Çıktı: u8 aralığı: 0 - 255
}
Biçimlendirme Belirteçleri
+ {d}: Ondalık sayı (tam sayı ve ondalıklı).+ {s}: String ([]const u8).
+ {c}: Tek bir ASCII karakter.
+ {x}, {b}, {o}: Onaltılık, ikili ve sekizlik.
+ {e}: Bilimsel gösterim.
+ {any}: Herhangi bir tipi yazdırır. Dizileri ve struct'ları görmek için kullanışlıdır.
+ {d:.2}, {d:>6}: Virgülden sonra 2 basamak ve 6 karakter genişlikte sağa yaslı.
+ {{ ve }}: Süslü parantezin kendisini yazdırmak için çift yazılır.
Kod:
std.debug.print("{d} {x} {b} {o}\n", .{ 255, 255, 5, 8 });
// Çıktı: 255 ff 101 10
std.debug.print("[{d:>6}]\n", .{42});
// Çıktı: [ 42]
Tip Dönüşümleri?
Zig'de tipler arası dönüşüm bilinçli yapılır. Bilgi kaybı olmayan dönüşümler (mesela u8'den u32'ye) otomatiktir, bilgi kaybı olabilecek dönüşümler için derleyici açık bir yerleşik fonksiyon ister:+ @as(T, değer): Güvenli, açık tip belirleme.
+ @intCast(x): Tam sayıyı başka bir tam sayı tipine çevirir. Değer sığmazsa Debug ve ReleaseSafe modlarında program çöker (panic). Hedef tip, atamanın solundaki tipten alınır.
+ @truncate(x): Fazla bitleri keserek küçültür, çökmez.
+ @floatFromInt(x), @intFromFloat(x): Tam sayı ile ondalıklı arasında dönüşüm. Ondalıklıdan tam sayıya çevirirken küsurat atılır.
Kod:
const std = @import("std");
pub fn main() void {
const kucuk: u8 = 200;
const buyuk: u32 = kucuk; // genişleme otomatik
const sayi: i32 = 200;
const dar: u8 = @intCast(sayi); // daraltma açık yapılmalı
const ondalik: f64 = @floatFromInt(sayi); // tam sayıdan ondalığa
const tam: i32 = @intFromFloat(3.99); // 3 (küsurat atılır)
const kes: u8 = @truncate(@as(u32, 0x1FF)); // fazla bitler atılır: 255
std.debug.print("{d} {d} {d} {d} {d}\n", .{ buyuk, dar, ondalik, tam, kes });
// Çıktı: 200 200 200 3 255
}
Tam sayı ile ondalıklıyı doğrudan toplayamazsınız, önce birini dönüştürmeniz gerekir. Bu sıkıcı görünebilir ama bilgi kaybına yol açan sessiz dönüşümleri tamamen ortadan kaldırır.
Aritmetik Operatörler ve Taşma?
+ Aritmetik: +, -, *, /, %+ Karşılaştırma: ==, !=, <, >, <=, >=
+ Mantıksal: and, or, ! (&& ve || yoktur, kelimelerle yazılır)
+ Bit işlemleri: &, |, ^, ~, <<, >>
+ Atama: =, +=, -=, *=, /= vb. (++ ve -- yoktur, i += 1 yazılır)
Kod:
const std = @import("std");
pub fn main() void {
const bolum: u32 = 17 / 5; // 3 (tam sayı bölmesi)
const kalan: u32 = 17 % 5; // 2
const ondalik: f64 = 17.0 / 5.0; // 3.4
const negatif = @divTrunc(@as(i32, -17), 5); // -3 (sıfıra doğru yuvarlar)
const mod = @mod(@as(i32, -17), 5); // 3 (sonuç hep pozitif)
std.debug.print("{d} {d} {d} {d} {d}\n", .{ bolum, kalan, ondalik, negatif, mod });
// Çıktı: 3 2 3.4 -3 3
}
İşaretli tam sayılarda / ve % operatörleri doğrudan kullanılamaz. Negatif sayıda sonuç belirsiz olabileceği için @divTrunc, @divFloor, @mod ya da @rem gibi hangi davranışı istediğinizi belirten fonksiyonlar kullanılır.
Tam Sayı Taşması (Overflow)
C'de işaretli tam sayı taşması tanımsız davranıştır. Zig'de taşma açıkça tanımlıdır: normal + operatörü taşarsa Debug ve ReleaseSafe modlarında program çöker (panic). Taşmayı kasten istiyorsanız ayrı operatörler kullanırsınız:+ +%, -%, *%: Sarmal (wrapping) aritmetik, taşınca başa döner.
+ +|, -|, *|: Doygun (saturating) aritmetik, tipin sınırında kalır.
+ @addWithOverflow, @subWithOverflow, @mulWithOverflow: Sonucu ve taşma bayrağını birlikte döndürür.
+ std.math.add, sub, mul: Taşarsa error.Overflow hatası döndürür.
Kod:
const std = @import("std");
pub fn main() void {
const a: u8 = 250;
const sarmal = a +% 10; // 260 % 256 = 4
const doygun = a +| 10; // 255'te kalır
const sonuc = @addWithOverflow(a, 10); // (değer, taşma bayrağı)
std.debug.print("sarmal={d} doygun={d}\n", .{ sarmal, doygun });
// Çıktı: sarmal=4 doygun=255
std.debug.print("değer={d} taşma={d}\n", .{ sonuc[0], sonuc[1] });
// Çıktı: değer=4 taşma=1
const guvenli = std.math.add(u8, a, 10) catch |hata| {
std.debug.print("hata: {s}\n", .{@errorName(hata)});
return;
};
std.debug.print("{d}\n", .{guvenli});
// Çıktı: hata: Overflow
}
Burada a sabit ve değeri derleme zamanında bilindiği için düz a + 10 yazsaydınız taşma derleme hatası olurdu. Değer çalışma zamanında gelseydi program çökerdi. Derleme modları bölümünde ReleaseFast'te bu kontrollerin kapandığını göreceğiz.
Karar Yapıları?
if / else
Koşul parantez içinde yazılır ve mutlaka bool olmalıdır (0 ya da null "yanlış" sayılmaz). if bir ifade (expression) olarak da kullanılabilir:
Kod:
const std = @import("std");
fn degerlendir(puan: u32) []const u8 {
if (puan >= 90) {
return "Mükemmel";
} else if (puan >= 70) {
return "İyi";
} else {
return "Daha çok çalış";
}
}
fn gectiMi(puan: u32) []const u8 {
return if (puan >= 50) "Geçti" else "Kaldı"; // if ifade olarak
}
pub fn main() void {
std.debug.print("{s} / {s}\n", .{ degerlendir(85), gectiMi(85) });
// Çıktı: İyi / Geçti
}

